[snippet] GeometryLibBase

Scripts

13 years

edited 8 years

Description

Here's the first of the codes developed to form a set of libraries with their dependencies so you can make in your map a complete but adapted geometry pack, fitting your needs and reducing redundant code. This code offers the most common functions required in geometry.

Requirements:

- /******************************************************************2

*                     GEOMETRY LIB PACK V1.3                      *

*                           By moyack                             *

*                              2012                               *

*              ===================================                *

*              Exclusive resource from wc3jass.com                *

*              ===================================                *

******************************************************************/

library GeometryLibBase requires GetZ

/*This is the first of a set of libraries focused in the usage of

proper geometry functions.

Here we'll aim to make the code as modular as possible so we can

reduce the code amount in map but offering the neccesary tools

for modders

Here we offer the most basic functions ever needed:

Atan3: to calculate PROPERLY the correct angle. the values (x1;y1)

       will be the pivot and (x2;y2) the extreme point.

GetDistance: Get the distance from (x1;y1) and (x2;y2). simple as hell

GetDistanceZ: Similar to GetDistance, but this one takes into account

              the terrain height.

Zangle: Returns the angle in Z coordinate (height) between 2 points.

GetPolarX: returns the X coordinate o a point from an initial value

           of "x" at an "angle" specified in a distance "d"

GetPolarY: returns the Y coordinate o a point from an initial value

           of "y" at an "angle" specified in a distance "d"

Important Note: Atan3 and Zangle returns the angles in RADIANS.

                GetPolaX/Y takes angles in RADIANS.

*/

function Atan3 takes real x1, real y1, real x2, real y2 returns real

    local real a = Atan2(y2 - y1, x2 - x1)

    if a < 0 then

        return 2 * bj_PI + a

    endif

    return a

endfunction

function GetDistance takes real x1, real y1, real x2, real y2 returns real

    local real dx = x2 - x1

    local real dy = y2 - y1

    return SquareRoot( dx * dx + dy * dy )

endfunction

function GetDistanceZ takes real x1, real y1, real x2, real y2 returns real

    local real dx = x2 - x1

    local real dy = y2 - y1

    local real dz = GetPointZ(x2, y2) - GetPointZ(x1, y1)

    return SquareRoot( dx * dx + dy * dy +  dz * dz)

endfunction

function GetZangle takes real x1, real y1, real x2, real y2 returns real

    return Acos(GetDistance(x1, y1, x2, y2) / GetDistanceZ(x1, y1, x2, y2))

endfunction

function GetPolarX takes real x, real radians, real d returns real

    return x + Cos(radians) * d

endfunction

function GetPolarY takes real y, real radians, real d returns real

    return y + Sin(radians) * d

endfunction

endlibrary

Changelog:
v1.0: Initial Release
v1.1: Added new functions. Added dependency to GetZ library.
v1.2: Added GetPolarX/Y functions.
v1.3: Changed a function name.

Any comments and suggestions are welcome.

13 years

Perhaps distance with z, just for kicks. I'll try to think of some more things to include.

13 years

Quote from: Purgeandfire on October 03, 2012, 01:54:37 AM
Perhaps distance with z, just for kicks. I'll try to think of some more things to include.

Awesome!! the idea is to make a full set of functions related for geometry. Right now I'm working in a group loop handler snippet so we can develop group units by certain conditions with less code.

13 years

Cool, but I'd prefer it if you added more functions like GetZAngle and name the functions properly (Distance -> GetDistance)

13 years

Quote from: Magtheridon96 on October 08, 2012, 01:49:04 PM
Cool, but I'd prefer it if you added more functions like GetZAngle and name the functions properly (Distance -> GetDistance)

Code updated, please check first post.

13 years

Code updated

13 years

But Zangle isn't a good function name

13 years

Quote from: Magtheridon96 on October 28, 2012, 09:52:34 AM
But Zangle isn't a good function name

Hmmm, what do you suggest???

13 years

A standard approach would arrive at GetZAngle :p

13 years

Quote from: Magtheridon96 on October 29, 2012, 08:24:40 AM
A standard approach would arrive at GetZAngle :p

Ok, done. Now it's called GetZangle()

13 years

Approved.

User Login